source: trunk/packages/libyaml/configure.ac @ 1934

Last change on this file since 1934 was 898, checked in by hartmans, 16 years ago

Add pyyaml and libyaml packages
backported from lenny.
There is discussion about how these should go in the repository; these are added in this form
in order to make forward progress.

File size: 2.2 KB
Line 
1# Run `./bootstrap` to generate the "configure" script.
2
3# Define the package version numbers and the bug reporting link.
4m4_define([YAML_MAJOR], 0)
5m4_define([YAML_MINOR], 1)
6m4_define([YAML_PATCH], 1)
7m4_define([YAML_BUGS], [http://pyyaml.org/newticket?component=libyaml])
8
9# Define the libtool version numbers; check the Autobook, Section 11.4.
10# Bump the libtool version numbers using the following algorithm:
11#   if (the current interface has not been changed):
12#       YAML_REVISION += 1
13#   else:
14#       YAML_REVISION = 0
15#       YAML_CURRENT += 1
16#       if (this release is backward compatible with the previous release):
17#           YAML_AGE += 1
18#       else:
19#           YAML_AGE = 0
20m4_define([YAML_RELEASE], 0)
21m4_define([YAML_CURRENT], 1)
22m4_define([YAML_REVISION], 0)
23m4_define([YAML_AGE], 0)
24
25# Initialize autoconf & automake.
26AC_PREREQ(2.59)
27AC_INIT([yaml], [YAML_MAJOR.YAML_MINOR.YAML_PATCH], [YAML_BUGS])
28AC_CONFIG_AUX_DIR([config])
29AC_CONFIG_HEADERS([config.h])
30AM_INIT_AUTOMAKE([1.9 foreign])
31
32# Define macro variables for the package version numbers.
33AC_DEFINE(YAML_VERSION_MAJOR, YAML_MAJOR, [Define the major version number.])
34AC_DEFINE(YAML_VERSION_MINOR, YAML_MINOR, [Define the minor version number.])
35AC_DEFINE(YAML_VERSION_PATCH, YAML_PATCH, [Define the patch version number.])
36AC_DEFINE(YAML_VERSION_STRING, "YAML_MAJOR.YAML_MINOR.YAML_PATCH", [Define the version string.])
37
38# Define substitutions for the libtool version numbers.
39YAML_LT_RELEASE=YAML_RELEASE
40YAML_LT_CURRENT=YAML_CURRENT
41YAML_LT_REVISION=YAML_REVISION
42YAML_LT_AGE=YAML_AGE
43AC_SUBST(YAML_LT_RELEASE)
44AC_SUBST(YAML_LT_CURRENT)
45AC_SUBST(YAML_LT_REVISION)
46AC_SUBST(YAML_LT_AGE)
47
48# Note: in order to update checks, run `autoscan` and look through "configure.scan".
49
50# Checks for programs.
51AC_PROG_CC
52AC_PROG_CPP
53AC_PROG_INSTALL
54AC_PROG_LN_S
55AC_PROG_MAKE_SET
56AC_PROG_LIBTOOL
57
58AC_CHECK_PROG(DOXYGEN, [doxygen], [true], [false])
59AM_CONDITIONAL(DOXYGEN, [test "$DOXYGEN" = true])
60
61# Checks for header files.
62AC_HEADER_STDC
63AC_CHECK_HEADERS([stdlib.h])
64
65# Checks for typedefs, structures, and compiler characteristics.
66AC_C_CONST
67AC_TYPE_SIZE_T
68
69# Define Makefiles.
70AC_CONFIG_FILES([include/Makefile src/Makefile Makefile tests/Makefile])
71
72# Generate the "configure" script.
73AC_OUTPUT
Note: See TracBrowser for help on using the repository browser.